Delphi-AI-Developer/Src/CodeCompletion/DelphiAIDev.CodeCompletion.Search.pas at fb83f2813b7b8fc505c27b06b68ec73e8c3d48fd · Code4Delphi/Delphi-AI-Developer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
unit DelphiAIDev.CodeCompletion.Search;

interface

uses
  System.SysUtils,
  System.Classes,
  Vcl.Forms,
  Vcl.Controls,
  ToolsAPI,
  DelphiAIDev.Types,
  DelphiAIDev.Consts,
  DelphiAIDev.Settings,
  DelphiAIDev.Utils,
  DelphiAIDev.Utils.OTA,
  DelphiAIDev.CodeCompletion.Vars,
  DelphiAIDev.AI.Facade;

type
  IDelphiAIDevCodeCompletionSearch = interface
    ['{5F8BDEE9-14DC-4C8C-BA7A-681A94844AD8}']
    procedure Process(const AContext: IOTAKeyContext);
  end;

  TDelphiAIDevCodeCompletionSearch = class(TInterfacedObject, IDelphiAIDevCodeCompletionSearch)
  private
    FSettings: TDelphiAIDevSettings;
    FQuestions: TStrings;
    FAIRequest: TDelphiAIDevAIFacade;
    FVars: TDelphiAIDevCodeCompletionVars;
    FIOTAEditPosition: IOTAEditPosition;
    procedure ProcessQuestions(const AContext: IOTAKeyContext);
    procedure ProcessResponse;
  protected
    procedure Process(const AContext: IOTAKeyContext);
  public
    class function New: IDelphiAIDevCodeCompletionSearch;
    constructor Create;
    destructor Destroy; override;
  end;

implementation

uses
  DelphiAIDev.Utils.Context;

class function TDelphiAIDevCodeCompletionSearch.New: IDelphiAIDevCodeCompletionSearch;
begin
  Result := Self.Create;
end;

constructor TDelphiAIDevCodeCompletionSearch.Create;
begin
  FSettings := TDelphiAIDevSettings.GetInstance;
  FAIRequest := TDelphiAIDevAIFacade.Create;
  FQuestions := TStringList.Create;
  FVars := TDelphiAIDevCodeCompletionVars.GetInstance;
end;

destructor TDelphiAIDevCodeCompletionSearch.Destroy;
begin
  FQuestions.Free;
  FAIRequest.Free;
  inherited;
end;

procedure TDelphiAIDevCodeCompletionSearch.Process(const AContext: IOTAKeyContext);
begin
  FSettings.ValidateFillingSelectedAICodeCompletion(TShowMsg.No);

  Screen.Cursor := crHourGlass;
  try
    Self.ProcessQuestions(AContext);

    try
      FAIRequest.AiUse(FSettings.CodeCompletionAIDefault).ProcessSend(FQuestions.Text);
    except
      Abort;
    end;

    Self.ProcessResponse;
  finally
    Screen.Cursor := crDefault;
  end;
end;

procedure TDelphiAIDevCodeCompletionSearch.ProcessQuestions(const AContext: IOTAKeyContext);
begin
  FVars.FullUnitInterface := TUtilsContext.GetUnitInterfaceCode;

  FQuestions.Clear;
  if not FVars.FullUnitInterface.Trim.IsEmpty then
    FQuestions.Add('Unit Interface Context:' + sLineBreak + FVars.FullUnitInterface);
  FQuestions.Add(FSettings.LanguageQuestions.GetLanguageDefinition);
  FQuestions.Add(FSettings.LanguageQuestions.GetMsgCodeCompletionSuggestion);
  FQuestions.Add(FSettings.LanguageQuestions.GetMsgCodeOnly);
  if not FSettings.CodeCompletionDefaultPrompt.Trim.IsEmpty then
    FQuestions.Add(FSettings.CodeCompletionDefaultPrompt);

  FIOTAEditPosition := AContext.EditBuffer.EditPosition;
  FIOTAEditPosition.InsertText(TConsts.TAG_CODE_COMPLETION);
  try
    FQuestions.Add(TUtilsOTA.GetSelectedBlockOrAllCodeUnit.Trim);
  finally
    FIOTAEditPosition.BackspaceDelete(TConsts.TAG_CODE_COMPLETION.Length);
  end;
end;

procedure TDelphiAIDevCodeCompletionSearch.ProcessResponse;
var
  LRow: Integer;
  LColumn: Integer;
  LBlankTextLines: string;
  i: Integer;
begin
  if FAIRequest.Response.GetStatusCode <> 200 then
  begin
    TUtils.ShowMsg('Unable to perform AI request.',
      Format('Code: %d %s Message: %s', [FAIRequest.Response.GetStatusCode, sLineBreak, FAIRequest.Response.GetContent.Text]));
    Exit;
  end;

  FVars.Module := TUtilsOTA.GetCurrentModule;
  FVars.Contents.Text := TUtils.ConfReturnAI(FAIRequest.Response.GetContent.Text);
  LRow := FIOTAEditPosition.Row;
  LColumn := FIOTAEditPosition.Column;

  FVars.Row := LRow;
  FVars.Column := LColumn;
  FVars.LineIni := LRow;
  FVars.LineEnd := FVars.LineIni + FVars.Contents.Count;

  LBlankTextLines := '';
  for i := 1 to Pred(FVars.Contents.Count) do
    LBlankTextLines := LBlankTextLines + sLineBreak;

  FIOTAEditPosition.InsertText(LBlankTextLines);
  FIOTAEditPosition.Move(FVars.LineIni, LColumn);
end;

end.