Optimize loop.getaddrinfo(): see if the address is an IP address already

Author: 1st1

uvloop/dns.pyx

@@ -1,3 +1,24 @@
+cdef __port_to_int(port, proto):
+    if port is None or port == '' or port == b'':
+        return 0
+
+    try:
+        return int(port)
+    except (ValueError, TypeError):
+        pass
+
+    if isinstance(port, bytes):
+        port = port.decode()
+
+    if isinstance(port, str) and proto is not None:
+        if proto == uv.IPPROTO_TCP:
+            return socket_getservbyname(port, 'tcp')
+        elif proto == uv.IPPROTO_UDP:
+            return socket_getservbyname(port, 'udp')
+
+    raise OSError('service/proto not found')
+
+
 cdef __convert_sockaddr_to_pyaddr(const system.sockaddr* addr):
     # Converts sockaddr structs into what Python socket
     # module can understand:
@@ -54,13 +75,11 @@ cdef __convert_pyaddr_to_sockaddr(int family, object addr,
             raise ValueError('AF_INET address must be tuple of (host, port)')
         host, port = addr
         if isinstance(host, str):
-            host = host.encode()
+            host = host.encode('idna')
         if not isinstance(host, (bytes, bytearray)):
             raise TypeError('host must be a string or bytes object')
-        if isinstance(port, bytes):
-            port = port.decode()
-        if isinstance(port, str):
-            port = int(port)
+
+        port = __port_to_int(port, None)
 
         err = uv.uv_ip4_addr(host, <int>port, <system.sockaddr_in*>res)
         if err < 0:
@@ -78,9 +97,10 @@ cdef __convert_pyaddr_to_sockaddr(int family, object addr,
 
         host = addr[0]
         if isinstance(host, str):
-            host = host.encode()
+            host = host.encode('idna')
+
+        port = __port_to_int(addr[1], None)
 
-        port = addr[1]
         if addr_len > 2:
             flowinfo = addr[2]
         if addr_len > 3:
@@ -98,6 +118,64 @@ cdef __convert_pyaddr_to_sockaddr(int family, object addr,
             'epected AF_INET or AF_INET6 family, got {}'.format(family))
 
 
+cdef __static_getaddrinfo(object host, object port,
+                          int family, int type,
+                          int proto,
+                          system.sockaddr *addr):
+
+    if proto not in {0, uv.IPPROTO_TCP, uv.IPPROTO_UDP}:
+        raise LookupError
+
+    type &= ~_SOCKET_TYPE_MASK
+    if type == uv.SOCK_STREAM:
+        proto = uv.IPPROTO_TCP
+    elif type == uv.SOCK_DGRAM:
+        proto = uv.IPPROTO_UDP
+    else:
+        raise LookupError
+
+    try:
+        port = __port_to_int(port, proto)
+    except:
+        raise LookupError
+
+    if family == uv.AF_UNSPEC:
+        afs = [uv.AF_INET, uv.AF_INET6]
+    else:
+        afs = [family]
+
+    for af in afs:
+        try:
+            __convert_pyaddr_to_sockaddr(af, (host, port), addr)
+        except:
+            continue
+        else:
+            return (af, type, proto)
+
+    raise LookupError
+
+
+cdef __static_getaddrinfo_pyaddr(object host, object port,
+                                 int family, int type,
+                                 int proto, int flags):
+
+    cdef:
+        system.sockaddr addr
+
+    try:
+        (af, type, proto) = __static_getaddrinfo(host, port, family, type,
+                                                 proto, &addr)
+    except LookupError:
+        return
+
+    try:
+        pyaddr = __convert_sockaddr_to_pyaddr(&addr)
+    except:
+        return
+
+    return af, type, proto, '', pyaddr
+
+
 @cython.freelist(DEFAULT_FREELIST_SIZE)
 cdef class AddrInfo:
     cdef:

uvloop/includes/stdlib.pxi

@@ -55,6 +55,7 @@ cdef socket_gaierror = socket.gaierror
 cdef socket_error = socket.error
 cdef socket_timeout = socket.timeout
 cdef socket_socket = socket.socket
+cdef socket_getservbyname = socket.getservbyname
 
 cdef int socket_EAI_ADDRFAMILY = getattr(socket, 'EAI_ADDRFAMILY', -1)
 cdef int socket_EAI_AGAIN      = getattr(socket, 'EAI_AGAIN', -1)
@@ -72,6 +73,13 @@ cdef int socket_EAI_SERVICE    = getattr(socket, 'EAI_SERVICE', -1)
 cdef int socket_EAI_SOCKTYPE   = getattr(socket, 'EAI_SOCKTYPE', -1)
 
 
+cdef int _SOCKET_TYPE_MASK = 0
+if hasattr(socket, 'SOCK_NONBLOCK'):
+    _SOCKET_TYPE_MASK |= socket.SOCK_NONBLOCK
+if hasattr(socket, 'SOCK_CLOEXEC'):
+    _SOCKET_TYPE_MASK |= socket.SOCK_CLOEXEC
+
+
 cdef str os_name = os.name
 cdef os_environ = os.environ
 cdef os_dup = os.dup

uvloop/includes/uv.pxd

@@ -62,6 +62,8 @@ cdef extern from "uv.h" nogil:
     cdef int IPPROTO_IPV6
     cdef int SOCK_STREAM
     cdef int SOCK_DGRAM
+    cdef int IPPROTO_TCP
+    cdef int IPPROTO_UDP
 
     cdef int SIGINT
     cdef int SIGHUP

uvloop/loop.pyx

@@ -1105,6 +1105,13 @@ cdef class Loop:
     def getaddrinfo(self, object host, object port, *,
                     int family=0, int type=0, int proto=0, int flags=0):
 
+        addr = __static_getaddrinfo_pyaddr(host, port, family,
+                                           type, proto, flags)
+        if addr is not None:
+            fut = self._new_future()
+            fut.set_result([addr])
+            return fut
+
         return self._getaddrinfo(host, port, family, type, proto, flags, 1)
 
     async def getnameinfo(self, sockaddr, int flags=0):