Thrust CMake conversion:

 * Make everything compile with GCC 8.
 * Run both tests and examples through CMake scripts instead of
 directly. This is needed for FileCheck, but will also be needed for
 DVS prints, or any other kinds of test status prints, that we may
 want/need in the future.
 * Support FileCheck for examples.

Author: griwes

CMakeLists.txt

@@ -2,6 +2,9 @@ cmake_minimum_required(VERSION 3.8)
 
 project(Thrust CXX)
 
+set(THRUST_SOURCE ${CMAKE_SOURCE_DIR})
+include(cmake/common_variables.cmake)
+
 # Default to a release build.
 if ("" STREQUAL "${CMAKE_BUILD_TYPE}")
   set(CMAKE_BUILD_TYPE "RelWithDebInfo" CACHE STRING "Choose the type of build." FORCE)
@@ -177,6 +180,12 @@ if ("GNU" STREQUAL "${CMAKE_CXX_COMPILER_ID}")
     # becoming part of the type system; we don't care.
     append_option_if_available("-Wnoexcept-type" THRUST_CXX_WARNINGS)
   endif ()
+
+  if (CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL 8.1 AND CMAKE_CXX_STANDARD EQUAL 98)
+    # thrust::complex can't really be made trivially copyable in pre-11
+    # disable a warning about a non-trivially-copyable type being memmoved that was added to GCC 8
+    append_option_if_available("-Wno-class-memaccess" THRUST_CXX_WARNINGS)
+  endif ()
 endif ()
 
 if (("Clang" STREQUAL "${CMAKE_CXX_COMPILER_ID}") OR
@@ -319,6 +328,10 @@ enable_testing()
 
 # Handle tests
 
+set(THRUST_TEST_RUN_ARGUMENTS
+  -DTHRUST_SOURCE=${CMAKE_SOURCE_DIR}
+  -P "${CMAKE_SOURCE_DIR}/cmake/run_test.cmake")
+
 list(APPEND THRUST_TESTFRAMEWORK_FILES testing/unittest/testframework.cu)
 if ("CUDA" STREQUAL "${THRUST_DEVICE_SYSTEM}")
   list(APPEND THRUST_TESTFRAMEWORK_FILES testing/unittest/cuda/testframework.cu)
@@ -447,7 +460,10 @@ foreach (THRUST_TEST_SOURCE IN LISTS THRUST_TESTS)
     ${THRUST_ADDITIONAL_LIBRARIES})
 
   if (THRUST_TEST_ADD_TO_CTEST)
-    add_test(${THRUST_TEST}     ${THRUST_TEST})
+    add_test(NAME ${THRUST_TEST}
+      COMMAND ${CMAKE_COMMAND}
+        -DTHRUST_BINARY=$<TARGET_FILE:${THRUST_TEST}>
+        ${THRUST_TEST_RUN_ARGUMENTS})
   endif ()
 
   if ("CUDA" STREQUAL "${THRUST_DEVICE_SYSTEM}")
@@ -474,7 +490,10 @@ foreach (THRUST_TEST_SOURCE IN LISTS THRUST_TESTS)
       PROPERTIES CUDA_SEPARABLE_COMPILATION ON)
 
     if (THRUST_TEST_ADD_TO_CTEST)
-      add_test(${THRUST_TEST_RDC} ${THRUST_TEST_RDC})
+      add_test(NAME ${THRUST_TEST_RDC}
+        COMMAND ${CMAKE_COMMAND}
+          -DTHRUST_BINARY=$<TARGET_FILE:${THRUST_TEST_RDC}>
+          ${THRUST_TEST_RUN_ARGUMENTS})
     endif ()
   endif ()
 endforeach ()
@@ -484,6 +503,20 @@ endforeach ()
 option(THRUST_EXAMPLE_FILECHECK_PATH "Path to the LLVM FileCheck utility." "")
 option(THRUST_ENABLE_EXAMPLES_WITH_RDC "Also build all examples with RDC." OFF)
 
+set(THRUST_EXAMPLE_FILECHECK_ENABLED OFF)
+if (NOT "" STREQUAL "${THRUST_EXAMPLE_FILECHECK_PATH}")
+  execute_process(
+    COMMAND "${THRUST_EXAMPLE_FILECHECK_PATH}" "${THRUST_FILECHECK_DATA_PATH}/thrust.sanity.filecheck"
+    INPUT_FILE "${CMAKE_SOURCE_DIR}/cmake/sanity"
+    RESULT_VARIABLE THRUST_FILECHECK_RESULT
+  )
+
+  if ("0" STREQUAL "${THRUST_FILECHECK_RESULT}")
+    set(THRUST_EXAMPLE_FILECHECK_ENABLED ON)
+    message("-- FileCheck enabled: ${THRUST_EXAMPLE_FILECHECK_PATH}")
+  endif ()
+endif ()
+
 list(APPEND THRUST_EXAMPLE_GLOBS examples/*.cu)
 list(APPEND THRUST_EXAMPLE_GLOBS examples/*.cpp)
 
@@ -509,6 +542,12 @@ else ()
   )
 endif ()
 
+set(THRUST_EXAMPLE_RUN_ARGUMENTS
+  -DTHRUST_SOURCE=${CMAKE_SOURCE_DIR}
+  -DTHRUST_FILECHECK_ENABLED=${THRUST_EXAMPLE_FILECHECK_ENABLED}
+  -DTHRUST_FILECHECK=${THRUST_EXAMPLE_FILECHECK_PATH}
+  -P "${CMAKE_SOURCE_DIR}/cmake/run_example.cmake")
+
 foreach (THRUST_EXAMPLE_SOURCE IN LISTS THRUST_EXAMPLES)
   # TODO: Per-example flags.
 
@@ -545,7 +584,11 @@ foreach (THRUST_EXAMPLE_SOURCE IN LISTS THRUST_EXAMPLES)
   target_link_libraries(${THRUST_EXAMPLE}
     ${THRUST_ADDITIONAL_LIBRARIES})
 
-  add_test(${THRUST_EXAMPLE}     ${THRUST_EXAMPLE})
+  add_test(NAME ${THRUST_EXAMPLE}
+    COMMAND ${CMAKE_COMMAND}
+      -DTHRUST_EXAMPLE=${THRUST_EXAMPLE}
+      -DTHRUST_BINARY=$<TARGET_FILE:${THRUST_EXAMPLE}>
+      ${THRUST_EXAMPLE_RUN_ARGUMENTS})
 
   if ("CUDA" STREQUAL "${THRUST_DEVICE_SYSTEM}" AND THRUST_ENABLE_EXAMPLES_WITH_RDC)
     set(THRUST_EXAMPLE_RDC "thrust.example.${THRUST_EXAMPLE_CATEGORY}rdc.${THRUST_EXAMPLE_NAME}")
@@ -567,7 +610,11 @@ foreach (THRUST_EXAMPLE_SOURCE IN LISTS THRUST_EXAMPLES)
     set_target_properties(${THRUST_EXAMPLE_RDC}
       PROPERTIES CUDA_SEPERABLE_COMPILATION ON)
 
-    add_test(${THRUST_EXAMPLE_RDC} ${THRUST_EXAMPLE_RDC})
+    add_test(NAME ${THRUST_EXAMPLE_RDC}
+      COMMAND ${CMAKE_COMMAND}
+        -DTHRUST_EXAMPLE=${THRUST_EXAMPLE}
+        -DTHRUST_BINARY=$<TARGET_FILE:${THRUST_EXAMPLE_RDC}>
+        ${THRUST_EXAMPLE_RUN_ARGUMENTS})
   endif ()
 endforeach ()
 

cmake/common_variables.cmake

@@ -0,0 +1 @@
+set(THRUST_FILECHECK_DATA_PATH "${THRUST_SOURCE}/internal/test")

cmake/run_example.cmake

@@ -0,0 +1,34 @@
+include("${THRUST_SOURCE}/cmake/common_variables.cmake")
+
+if (THRUST_FILECHECK_ENABLED)
+  set(DATA_FILE "${THRUST_FILECHECK_DATA_PATH}/${THRUST_EXAMPLE}.filecheck")
+  file(READ "${DATA_FILE}" CONTENTS)
+  string(LENGTH "${CONTENTS}" LENGTH)
+  message(${LENGTH})
+
+  if (NOT ${LENGTH} EQUAL 0)
+    set(FILECHECK_COMMAND
+      COMMAND "${THRUST_FILECHECK}" "${THRUST_FILECHECK_DATA_PATH}/${THRUST_EXAMPLE}.filecheck")
+  else ()
+    set(CHECK_EMPTY_OUTPUT TRUE)
+  endif ()
+endif ()
+
+execute_process(
+  COMMAND "${THRUST_BINARY}"
+  ${FILECHECK_COMMAND}
+  RESULT_VARIABLE EXIT_CODE
+  OUTPUT_VARIABLE STDOUT
+  ERROR_VARIABLE STDERR
+)
+
+if (NOT "0" STREQUAL "${EXIT_CODE}")
+  message(FATAL_ERROR "${THRUST_BINARY} failed (${EXIT_CODE}):\n${STDERR}")
+endif ()
+
+if (CHECK_EMPTY_OUTPUT)
+  string(LENGTH "${OUTPUT_VARIABLE}" LENGTH)
+  if (NOT ${LENGTH} EQUAL 0)
+    message(FATAL_ERROR "${THRUST_BINARY}: output received, but not expected.")
+  endif ()
+endif ()

cmake/run_test.cmake

@@ -0,0 +1,8 @@
+execute_process(
+  COMMAND "${THRUST_BINARY}"
+  RESULT_VARIABLE EXIT_CODE
+)
+
+if (NOT "0" STREQUAL "${EXIT_CODE}")
+    message(FATAL_ERROR "${THRUST_BINARY} failed (${EXIT_CODE})")
+endif ()

cmake/sanity

@@ -0,0 +1 @@
+SANITY

internal/test/thrust.example.monte_carlo_disjoint_sequences.filecheck

@@ -1 +1 @@
-     CHECK: pi is around 3.14151
+     CHECK: pi is around 3.1415