Add ProjectUser model, table, model tests

Author: begedin

priv/repo/migrations/20170228085250_create_project_users.exs

@@ -0,0 +1,15 @@
+defmodule CodeCorps.Repo.Migrations.CreateProjectUsers do
+  use Ecto.Migration
+
+  def change do
+    create table(:project_users) do
+      add :role, :string, null: false
+      add :project_id, references(:projects, on_delete: :nothing), null: false
+      add :user_id, references(:users, on_delete: :nothing), null: false
+
+      timestamps()
+    end
+
+    create index :project_users, [:user_id, :project_id], unique: true
+  end
+end

priv/repo/structure.sql

@@ -2,8 +2,8 @@
 -- PostgreSQL database dump
 --
 
--- Dumped from database version 9.5.4
--- Dumped by pg_dump version 9.5.4
+-- Dumped from database version 9.5.1
+-- Dumped by pg_dump version 9.5.1
 
 SET statement_timeout = 0;
 SET lock_timeout = 0;
@@ -318,6 +318,39 @@ CREATE SEQUENCE project_skills_id_seq
 ALTER SEQUENCE project_skills_id_seq OWNED BY project_skills.id;
 
 
+--
+-- Name: project_users; Type: TABLE; Schema: public; Owner: -
+--
+
+CREATE TABLE project_users (
+    id integer NOT NULL,
+    role character varying(255) NOT NULL,
+    project_id integer NOT NULL,
+    user_id integer NOT NULL,
+    inserted_at timestamp without time zone NOT NULL,
+    updated_at timestamp without time zone NOT NULL
+);
+
+
+--
+-- Name: project_users_id_seq; Type: SEQUENCE; Schema: public; Owner: -
+--
+
+CREATE SEQUENCE project_users_id_seq
+    START WITH 1
+    INCREMENT BY 1
+    NO MINVALUE
+    NO MAXVALUE
+    CACHE 1;
+
+
+--
+-- Name: project_users_id_seq; Type: SEQUENCE OWNED BY; Schema: public; Owner: -
+--
+
+ALTER SEQUENCE project_users_id_seq OWNED BY project_users.id;
+
+
 --
 -- Name: projects; Type: TABLE; Schema: public; Owner: -
 --
@@ -1364,6 +1397,13 @@ ALTER TABLE ONLY project_categories ALTER COLUMN id SET DEFAULT nextval('project
 ALTER TABLE ONLY project_skills ALTER COLUMN id SET DEFAULT nextval('project_skills_id_seq'::regclass);
 
 
+--
+-- Name: id; Type: DEFAULT; Schema: public; Owner: -
+--
+
+ALTER TABLE ONLY project_users ALTER COLUMN id SET DEFAULT nextval('project_users_id_seq'::regclass);
+
+
 --
 -- Name: id; Type: DEFAULT; Schema: public; Owner: -
 --
@@ -1603,6 +1643,14 @@ ALTER TABLE ONLY project_skills
     ADD CONSTRAINT project_skills_pkey PRIMARY KEY (id);
 
 
+--
+-- Name: project_users_pkey; Type: CONSTRAINT; Schema: public; Owner: -
+--
+
+ALTER TABLE ONLY project_users
+    ADD CONSTRAINT project_users_pkey PRIMARY KEY (id);
+
+
 --
 -- Name: projects_pkey; Type: CONSTRAINT; Schema: public; Owner: -
 --
@@ -1875,6 +1923,13 @@ CREATE UNIQUE INDEX project_skills_project_id_skill_id_index ON project_skills U
 CREATE INDEX project_skills_skill_id_index ON project_skills USING btree (skill_id);
 
 
+--
+-- Name: project_users_user_id_project_id_index; Type: INDEX; Schema: public; Owner: -
+--
+
+CREATE UNIQUE INDEX project_users_user_id_project_id_index ON project_users USING btree (user_id, project_id);
+
+
 --
 -- Name: projects_approved_index; Type: INDEX; Schema: public; Owner: -
 --
@@ -2229,6 +2284,22 @@ ALTER TABLE ONLY project_skills
     ADD CONSTRAINT project_skills_skill_id_fkey FOREIGN KEY (skill_id) REFERENCES skills(id);
 
 
+--
+-- Name: project_users_project_id_fkey; Type: FK CONSTRAINT; Schema: public; Owner: -
+--
+
+ALTER TABLE ONLY project_users
+    ADD CONSTRAINT project_users_project_id_fkey FOREIGN KEY (project_id) REFERENCES projects(id);
+
+
+--
+-- Name: project_users_user_id_fkey; Type: FK CONSTRAINT; Schema: public; Owner: -
+--
+
+ALTER TABLE ONLY project_users
+    ADD CONSTRAINT project_users_user_id_fkey FOREIGN KEY (user_id) REFERENCES users(id);
+
+
 --
 -- Name: projects_organization_id_fkey; Type: FK CONSTRAINT; Schema: public; Owner: -
 --
@@ -2537,5 +2608,5 @@ ALTER TABLE ONLY user_tasks
 -- PostgreSQL database dump complete
 --
 
-INSERT INTO "schema_migrations" (version) VALUES (20160723215749), (20160804000000), (20160804001111), (20160805132301), (20160805203929), (20160808143454), (20160809214736), (20160810124357), (20160815125009), (20160815143002), (20160816020347), (20160816034021), (20160817220118), (20160818000944), (20160818132546), (20160820113856), (20160820164905), (20160822002438), (20160822004056), (20160822011624), (20160822020401), (20160822044612), (20160830081224), (20160830224802), (20160911233738), (20160912002705), (20160912145957), (20160918003206), (20160928232404), (20161003185918), (20161019090945), (20161019110737), (20161020144622), (20161021131026), (20161031001615), (20161121005339), (20161121014050), (20161121043941), (20161121045709), (20161122015942), (20161123081114), (20161123150943), (20161124085742), (20161125200620), (20161126045705), (20161127054559), (20161205024856), (20161207112519), (20161209192504), (20161212005641), (20161214005935), (20161215052051), (20161216051447), (20161218005913), (20161219160401), (20161219163909), (20161220141753), (20161221085759), (20161226213600), (20161231063614), (20170102130055), (20170102181053), (20170104113708), (20170104212623), (20170104235423), (20170106013143), (20170115035159), (20170115230549), (20170121014100), (20170131234029), (20170201014901), (20170201025454), (20170201035458), (20170201183258), (20170220032224), (20170224233516), (20170226050552);
+INSERT INTO "schema_migrations" (version) VALUES (20160723215749), (20160804000000), (20160804001111), (20160805132301), (20160805203929), (20160808143454), (20160809214736), (20160810124357), (20160815125009), (20160815143002), (20160816020347), (20160816034021), (20160817220118), (20160818000944), (20160818132546), (20160820113856), (20160820164905), (20160822002438), (20160822004056), (20160822011624), (20160822020401), (20160822044612), (20160830081224), (20160830224802), (20160911233738), (20160912002705), (20160912145957), (20160918003206), (20160928232404), (20161003185918), (20161019090945), (20161019110737), (20161020144622), (20161021131026), (20161031001615), (20161121005339), (20161121014050), (20161121043941), (20161121045709), (20161122015942), (20161123081114), (20161123150943), (20161124085742), (20161125200620), (20161126045705), (20161127054559), (20161205024856), (20161207112519), (20161209192504), (20161212005641), (20161214005935), (20161215052051), (20161216051447), (20161218005913), (20161219160401), (20161219163909), (20161220141753), (20161221085759), (20161226213600), (20161231063614), (20170102130055), (20170102181053), (20170104113708), (20170104212623), (20170104235423), (20170106013143), (20170115035159), (20170115230549), (20170121014100), (20170131234029), (20170201014901), (20170201025454), (20170201035458), (20170201183258), (20170220032224), (20170224233516), (20170226050552), (20170228085250);
 

test/models/project_user_test.exs

@@ -0,0 +1,101 @@
+defmodule CodeCorps.ProjectUserTest do
+  use CodeCorps.ModelCase
+
+  alias CodeCorps.{ProjectUser, Repo}
+
+  describe "update_changeset role validation" do
+    test "includes pending" do
+      attrs = %{role: "pending"}
+      changeset = ProjectUser.update_changeset(%ProjectUser{}, attrs)
+      assert changeset.valid?
+    end
+
+    test "includes contributor" do
+      attrs = %{role: "contributor"}
+      changeset = ProjectUser.update_changeset(%ProjectUser{}, attrs)
+      assert changeset.valid?
+    end
+
+    test "includes admin" do
+      attrs = %{role: "admin"}
+      changeset = ProjectUser.update_changeset(%ProjectUser{}, attrs)
+      assert changeset.valid?
+    end
+
+    test "includes owner" do
+      attrs = %{role: "owner"}
+      changeset = ProjectUser.update_changeset(%ProjectUser{}, attrs)
+      assert changeset.valid?
+    end
+
+    test "does not include invalid values" do
+      attrs = %{role: "invalid"}
+      changeset = ProjectUser.update_changeset(%ProjectUser{}, attrs)
+      refute changeset.valid?
+    end
+  end
+
+  describe "create_owner_changeset/2" do
+    @attributes ~w(project_id user_id role)
+
+    test "casts #{@attributes}, with role cast to 'owner'" do
+      attrs = %{foo: "bar", project_id: 1, user_id: 2}
+      changeset = ProjectUser.create_owner_changeset(%ProjectUser{}, attrs)
+      assert changeset.changes == %{project_id: 1, user_id: 2, role: "owner"}
+    end
+
+    test "ensures user record exists" do
+      project = insert(:project)
+      attrs = %{project_id: project.id, user_id: -1}
+      changeset = ProjectUser.create_owner_changeset(%ProjectUser{}, attrs)
+
+      {:error, invalid_changeset} = changeset |> Repo.insert
+      refute invalid_changeset.valid?
+
+      assert assoc_constraint_triggered?(invalid_changeset, :user)
+    end
+
+    test "ensures project record exists" do
+      user = insert(:user)
+      attrs = %{project_id: -1, user_id: user.id}
+      changeset = ProjectUser.create_owner_changeset(%ProjectUser{}, attrs)
+
+      {:error, invalid_changeset} = changeset |> Repo.insert
+      refute invalid_changeset.valid?
+
+      assert assoc_constraint_triggered?(invalid_changeset, :project)
+    end
+  end
+
+  describe "create_pending_changeset/2" do
+    @attributes ~w(project_id user_id role)
+
+    test "casts #{@attributes}, with role cast to 'pending'" do
+      attrs = %{foo: "bar", project_id: 1, user_id: 2}
+      changeset = ProjectUser.create_pending_changeset(%ProjectUser{}, attrs)
+      assert changeset.changes == %{project_id: 1, user_id: 2, role: "pending"}
+    end
+
+    test "ensures user record exists" do
+      project = insert(:project)
+      attrs = %{project_id: project.id, user_id: -1}
+      changeset = ProjectUser.create_pending_changeset(%ProjectUser{}, attrs)
+
+      {:error, invalid_changeset} = changeset |> Repo.insert
+      refute invalid_changeset.valid?
+
+      assert assoc_constraint_triggered?(invalid_changeset, :user)
+    end
+
+    test "ensures project record exists" do
+      user = insert(:user)
+      attrs = %{project_id: -1, user_id: user.id}
+      changeset = ProjectUser.create_pending_changeset(%ProjectUser{}, attrs)
+
+      {:error, invalid_changeset} = changeset |> Repo.insert
+      refute invalid_changeset.valid?
+
+      assert assoc_constraint_triggered?(invalid_changeset, :project)
+    end
+  end
+end

test/support/model_case.ex

@@ -23,16 +23,6 @@ defmodule CodeCorps.ModelCase do
       import Ecto.Query
       import CodeCorps.Factories
       import CodeCorps.ModelCase
-
-      defp assert_error_message(changeset, field, expected_message) do
-        {actual_message, _} = changeset.errors[field]
-        assert actual_message == expected_message
-      end
-
-      defp assert_validation_triggered(changeset, field, type) do
-        {_message, status} = changeset.errors[field]
-        assert status[:validation] == type
-      end
     end
   end
 
@@ -73,4 +63,72 @@ defmodule CodeCorps.ModelCase do
     |> Ecto.Changeset.traverse_errors(&CodeCorps.ErrorHelpers.translate_error/1)
     |> Enum.flat_map(fn {key, errors} -> for msg <- errors, do: {key, msg} end)
   end
+
+  @doc """
+  Asserts if a specific error message has been added to a specific field on the
+  changeset. It is more flexible to use `error_message/2` directly instead of
+  this one.
+
+  ```
+  assert_error_message(changeset, :foo, "bar")
+  ```
+
+  Compared to
+
+  ```
+  assert error_message(changeset, :foo) ==  "bar"
+  refute error_message?(changeset, :foo) ==  "baz"
+  ```
+  """
+  def assert_error_message(changeset, field, expected_message) do
+    assert error_message(changeset, field) == expected_message
+  end
+
+  @doc """
+  Asserts if a specific validation type has been triggered on a specific field
+  on the changeset. It is more flexible to use `validation_triggered/2` directly
+  instead of this one.
+
+  ```
+  assert_validation_triggered(changeset, :foo, "bar")
+  ```
+
+  Compared to
+
+  ```
+  assert validation_triggered(changeset, :foo) ==  :required
+  refute validation_triggered?(changeset, :bar) ==  :required
+  ```
+  """
+  def assert_validation_triggered(changeset, field, type) do
+    assert validation_triggered(changeset, field) == type
+  end
+
+  @doc """
+  Returns an error message on a specific field on the specified changeset
+  """
+  @spec error_message(Ecto.Changeset.t, Atom.t) :: String.t
+  def error_message(changeset, field) do
+    {message, _} = changeset.errors[field]
+    message
+  end
+
+  @doc """
+  Returns an atom indicating the type of validation that was triggered on a
+  field in a changeset.
+  """
+  @spec validation_triggered(Ecto.Changeset.t, Atom.t) :: Atom.t
+  def validation_triggered(changeset, field) do
+    {_message, status} = changeset.errors[field]
+    status[:validation]
+  end
+
+  @doc """
+  Returns true or false depending on if an assoc_constraint validation has been
+  triggered in the provided changeset on the specified field.
+  """
+  @spec assoc_constraint_triggered?(Ecto.Changeset.t, Atom.t) :: boolean
+  def assoc_constraint_triggered?(changeset, field) do
+    error_message(changeset, field) == "does not exist"
+  end
 end

web/models/project_user.ex

@@ -0,0 +1,63 @@
+defmodule CodeCorps.ProjectUser do
+  @moduledoc """
+  Represents a membership of a user in a project.
+  """
+
+  use CodeCorps.Web, :model
+
+  @type t :: %__MODULE__{}
+
+  schema "project_users" do
+    field :role, :string
+
+    belongs_to :project, CodeCorps.Project
+    belongs_to :user, CodeCorps.User
+
+    timestamps()
+  end
+
+
+  @doc """
+  Builds a changeset to create a pending membership
+  """
+  def create_pending_changeset(struct, params \\ %{}) do
+    struct
+    |> create_changeset(params)
+    |> put_change(:role, "pending")
+  end
+
+  @doc """
+  Builds a changeset to create an owner membership
+  """
+  def create_owner_changeset(struct, params \\ %{}) do
+    struct
+    |> create_changeset(params)
+    |> put_change(:role, "owner")
+  end
+
+  @doc """
+  Builds a changeset for inserting a new record into the database
+  """
+  defp create_changeset(struct, params \\ %{}) do
+    struct
+    |> cast(params, [:user_id, :project_id])
+    |> validate_required([:user_id, :project_id])
+    |> assoc_constraint(:user)
+    |> assoc_constraint(:project)
+    |> unique_constraint(:project, name: :project_users_user_id_project_id_index)
+  end
+
+  @doc """
+  Builds a changeset for updating a record. Only the role can be updated.
+  """
+  def update_changeset(struct, params \\ %{}) do
+    struct
+    |> cast(params, [:role])
+    |> validate_required([:role])
+    |> validate_inclusion(:role, roles())
+  end
+
+  defp roles do
+    ~w{ pending contributor admin owner }
+  end
+end