Test Sync.GithubUser properly

Author: begedin

lib/code_corps/github/sync/github_user/changeset.ex

@@ -0,0 +1,18 @@
+defmodule CodeCorps.GitHub.Sync.GithubUser.Changeset do
+  @moduledoc ~S"""
+  In charge of changesets for actions on `CodeCorps.GithubUser` records.
+  """
+
+  alias CodeCorps.GithubUser
+  alias Ecto.Changeset
+
+  @doc ~S"""
+  Builds a changeset for creating or updating a `CodeCorps.GithubUser` record.
+  """
+  @spec changeset(GithubUser.t(), map) :: Changeset.t()
+  def changeset(%GithubUser{} = struct, %{} = attrs) do
+    struct
+    |> Changeset.cast(attrs, [:avatar_url, :email, :github_id, :username, :type])
+    |> Changeset.validate_required([:avatar_url, :github_id, :username, :type])
+  end
+end

lib/code_corps/github/sync/github_user/github_user.ex

@@ -4,27 +4,26 @@ defmodule CodeCorps.GitHub.Sync.GithubUser do
   containing the user.
   """
 
-  alias CodeCorps.{
-    GitHub.Adapters,
-    GithubUser,
-    Repo
-  }
+  alias CodeCorps.{GitHub.Adapters, GitHub.Sync, GithubUser, Repo}
 
   @doc ~S"""
   Finds or creates a `GithubUser` record using information in the GitHub API
   payload.
   """
   @spec create_or_update_github_user(map) :: {:ok, GithubUser.t}
-  def create_or_update_github_user(%{"user" => %{"id" => github_id} = attrs}) do
+  def create_or_update_github_user(%{"user" => %{"id" => github_id} = params}) do
+    attrs = params |> Adapters.User.to_github_user()
+
     case GithubUser |> Repo.get_by(github_id: github_id) do
       nil ->
         %GithubUser{}
-        |> GithubUser.changeset(attrs |> Adapters.User.to_github_user)
-        |> Repo.insert
-      %GithubUser{} = issue ->
-        issue
-        |> GithubUser.changeset(attrs |> Adapters.User.to_github_user)
-        |> Repo.update
+        |> Sync.GithubUser.Changeset.changeset(attrs)
+        |> Repo.insert()
+
+      %GithubUser{} = record ->
+        record
+        |> Sync.GithubUser.Changeset.changeset(attrs)
+        |> Repo.update()
     end
   end
 end

lib/code_corps/model/github_user.ex

@@ -1,6 +1,5 @@
 defmodule CodeCorps.GithubUser do
   use Ecto.Schema
-  import Ecto.Changeset
 
   @type t :: %__MODULE__{}
 
@@ -15,11 +14,4 @@ defmodule CodeCorps.GithubUser do
 
     timestamps()
   end
-
-  @doc false
-  def changeset(struct, attrs) do
-    struct
-    |> cast(attrs, [:avatar_url, :email, :github_id, :username, :type])
-    |> validate_required([:avatar_url, :github_id, :username, :type])
-  end
 end

test/lib/code_corps/github/sync/github_user/changeset_test.exs

@@ -0,0 +1,45 @@
+defmodule CodeCorps.GitHub.Event.GithubUser.ChangesetTest do
+  @moduledoc false
+
+  use CodeCorps.DbAccessCase
+
+  import CodeCorps.GitHub.TestHelpers
+  alias CodeCorps.{
+    GitHub.Adapters,
+    GitHub.Sync,
+    GithubUser
+  }
+  alias Ecto.Changeset
+
+
+  describe "changeset/2" do
+    test "assigns correct changes" do
+      attrs =
+        "issues_opened"
+        |> load_event_fixture()
+        |> Kernel.get_in(["issue", "user"])
+        |> Adapters.User.to_github_user()
+
+      changeset = %GithubUser{} |> Sync.GithubUser.Changeset.changeset(attrs)
+
+      assert changeset |> Changeset.get_change(:avatar_url) == attrs.avatar_url
+      assert changeset |> Changeset.get_change(:email) == attrs.email
+      assert changeset |> Changeset.get_change(:github_id) == attrs.github_id
+      assert changeset |> Changeset.get_change(:username) == attrs.username
+      assert changeset |> Changeset.get_change(:type) == attrs.type
+
+      assert changeset.valid?
+    end
+
+    test "validates correct required attributes" do
+      changeset = %GithubUser{} |> Sync.GithubUser.Changeset.changeset(%{})
+
+      refute changeset.valid?
+
+      assert changeset.errors[:avatar_url]
+      assert changeset.errors[:github_id]
+      assert changeset.errors[:username]
+      assert changeset.errors[:type]
+    end
+  end
+end

test/lib/code_corps/github/sync/github_user/github_user_test.exs

@@ -0,0 +1,55 @@
+defmodule CodeCorps.GitHub.Sync.GithubUserTest do
+  @moduledoc false
+
+  use CodeCorps.DbAccessCase
+
+  import CodeCorps.GitHub.TestHelpers
+
+  alias CodeCorps.{
+    GitHub.Adapters,
+    GitHub.Sync,
+    GithubUser,
+    Repo
+  }
+
+  alias Ecto.Changeset
+
+
+
+  @event_payload "issues_opened" |> load_event_fixture() |> Map.get("issue")
+
+  describe "create_or_update_github_user/1" do
+    test "creates github user if one is not matched from the payload" do
+      assert {:ok, %GithubUser{id: created_id}} =
+        @event_payload |> Sync.GithubUser.create_or_update_github_user()
+
+      assert created_user = Repo.one(GithubUser)
+      assert created_user.id == created_id
+      attrs = Adapters.User.to_github_user(@event_payload["user"])
+      assert created_user |> Map.take(attrs |> Map.keys()) == attrs
+    end
+
+    test "updates github user if one is matched from the payload" do
+      record = insert(:github_user, github_id: @event_payload["user"]["id"])
+
+      assert {:ok, %GithubUser{id: updated_id}} =
+        @event_payload |> Sync.GithubUser.create_or_update_github_user()
+
+      assert updated_user = Repo.one(GithubUser)
+      assert updated_user.id == updated_id
+      assert updated_user.id == record.id
+      attrs = Adapters.User.to_github_user(@event_payload["user"])
+      assert updated_user |> Map.take(attrs |> Map.keys()) == attrs
+    end
+
+    test "returns changeset if there was a problem" do
+      assert {:error, %Changeset{} = changeset} =
+        @event_payload
+        |> Kernel.put_in(["user", "login"], nil)
+        |> Sync.GithubUser.create_or_update_github_user()
+
+      refute changeset.valid?
+      refute Repo.one(GithubUser)
+    end
+  end
+end