Add status filtering to GitHub events (#1352)

* Add status filtering to github events

Author: joshsmith

lib/code_corps/admin/github_event_query.ex

@@ -0,0 +1,39 @@
+defmodule CodeCorps.Admin.GithubEventQuery do
+  @moduledoc ~S"""
+  Holds helpers to query `CodeCorps.GithubEvent` records using a map of params.
+  """
+
+  import Ecto.Query
+
+  alias Ecto.Queryable
+
+  @doc ~S"""
+  Filters a `CodeCorps.GithubEvent` query by `action`, if specified in params
+  """
+  @spec action_filter(Queryable.t, map) :: Queryable.t
+  def action_filter(queryable, %{"action" => action}) do
+    queryable
+    |> where([c], c.action == ^action)
+  end
+  def action_filter(queryable, %{}), do: queryable
+
+  @doc ~S"""
+  Filters a `CodeCorps.GithubEvent` query by `status`, if specified in params
+  """
+  @spec status_filter(Queryable.t, map) :: Queryable.t
+  def status_filter(queryable, %{"status" => status}) do
+    queryable
+    |> where([c], c.status == ^status)
+  end
+  def status_filter(queryable, %{}), do: queryable
+
+  @doc ~S"""
+  Filters a `CodeCorps.GithubEvent` query by `type`, if specified in params
+  """
+  @spec type_filter(Queryable.t, map) :: Queryable.t
+  def type_filter(queryable, %{"type" => type}) do
+    queryable
+    |> where([c], c.type == ^type)
+  end
+  def type_filter(queryable, %{}), do: queryable
+end

lib/code_corps_web/controllers/github_event_controller.ex

@@ -4,6 +4,7 @@ defmodule CodeCorpsWeb.GithubEventController do
   import Ecto.Query, only: [from: 2]
 
   alias CodeCorps.{
+    Admin,
     GithubEvent,
     GithubRepo,
     GitHub.Webhook.Handler,
@@ -26,6 +27,9 @@ defmodule CodeCorpsWeb.GithubEventController do
       github_events =
         GithubEvent
         |> Query.id_filter(params)
+        |> Admin.GithubEventQuery.action_filter(params)
+        |> Admin.GithubEventQuery.status_filter(params)
+        |> Admin.GithubEventQuery.type_filter(params)
         |> Ecto.Query.order_by([desc: :inserted_at])
         |> paginate(params)
 

test/lib/code_corps/admin/github_event_query_test.exs

@@ -0,0 +1,92 @@
+defmodule CodeCorps.Admin.GithubEventQueryTest do
+  @moduledoc false
+
+  use CodeCorps.DbAccessCase
+
+  alias CodeCorps.{
+    Admin.GithubEventQuery,
+    GithubEvent,
+    Repo
+  }
+
+  describe "action_filter/2" do
+    test "when action is present it filters" do
+      created_event = insert(:github_event, action: "created")
+      insert(:github_event, action: "opened")
+
+      [result] =
+        GithubEvent
+        |> GithubEventQuery.action_filter(%{"action" => "created"})
+        |> Repo.all()
+
+      assert created_event == result
+    end
+
+    test "when action is not present returns the queryable" do
+      created_event = insert(:github_event, action: "created")
+      opened_event = insert(:github_event, action: "opened")
+
+      [result1, result2] =
+        GithubEvent
+        |> GithubEventQuery.action_filter(%{})
+        |> Repo.all()
+
+      assert created_event == result1
+      assert opened_event == result2
+    end
+  end
+
+  describe "status_filter/2" do
+    test "when status is present it filters" do
+      processed_event = insert(:github_event, status: "processed")
+      insert(:github_event, status: "unprocessed")
+
+      [result] =
+        GithubEvent
+        |> GithubEventQuery.status_filter(%{"status" => "processed"})
+        |> Repo.all()
+
+      assert processed_event == result
+    end
+
+    test "when status is not present returns the queryable" do
+      processed_event = insert(:github_event, status: "processed")
+      unprocessed_event = insert(:github_event, status: "unprocessed")
+
+      [result1, result2] =
+        GithubEvent
+        |> GithubEventQuery.status_filter(%{})
+        |> Repo.all()
+
+      assert processed_event == result1
+      assert unprocessed_event == result2
+    end
+  end
+
+  describe "type_filter/2" do
+    test "when type is present it filters" do
+      created_event = insert(:github_event, type: "issues")
+      insert(:github_event, type: "installation")
+
+      [result] =
+        GithubEvent
+        |> GithubEventQuery.type_filter(%{"type" => "issues"})
+        |> Repo.all()
+
+      assert created_event == result
+    end
+
+    test "when type is not present returns the queryable" do
+      issues_event = insert(:github_event, type: "issues")
+      installation_event = insert(:github_event, type: "installation")
+
+      [result1, result2] =
+        GithubEvent
+        |> GithubEventQuery.type_filter(%{})
+        |> Repo.all()
+
+      assert issues_event == result1
+      assert installation_event == result2
+    end
+  end
+end

test/lib/code_corps_web/controllers/github_event_controller_test.exs

@@ -54,6 +54,21 @@ defmodule CodeCorpsWeb.GithubEventControllerTest do
       |> assert_ids_from_response([github_event_1.id, github_event_2.id])
     end
 
+    @tag authenticated: :admin
+    test "filters resources on index with query params", %{conn: conn} do
+      expected_event = insert(:github_event, action: "opened", status: "processed", type: "issues")
+      insert(:github_event, action: "created")
+      insert(:github_event, status: "unprocessed")
+      insert(:github_event, type: "installation")
+
+      path = "github-events/?action=opened&status=processed&type=issues"
+
+      conn
+      |> get(path)
+      |> json_response(200)
+      |> assert_ids_from_response([expected_event.id])
+    end
+
     test "renders 401 when unauthenticated", %{conn: conn} do
       assert conn |> request_index() |> json_response(401)
     end