Merge pull request #683 from code-corps/refactor-segment-tracking

Refactor segment tracking

Author: joshsmith

lib/code_corps/analytics/segment.ex

@@ -0,0 +1,25 @@
+defmodule CodeCorps.Analytics.SegmentDataExtractor do
+  @moduledoc """
+  Extract data for use in Segment tracking
+  """
+
+  @spec get_action(Plug.Conn.t) :: atom
+  def get_action(%Plug.Conn{private: %{phoenix_action: action}}), do: action
+
+  @spec get_resource(Plug.Conn.t) :: struct
+  def get_resource(%Plug.Conn{assigns: %{data: data}}), do: data
+  # these are used for delete actions on records that support it
+  # we render a 404 in those cases, so data is never assigned
+  def get_resource(%Plug.Conn{assigns: %{user_category: data}}), do: data
+  def get_resource(%Plug.Conn{assigns: %{user_role: data}}), do: data
+  def get_resource(%Plug.Conn{assigns: %{user_skill: data}}), do: data
+  def get_resource(%Plug.Conn{assigns: %{token: token, user_id: user_id}}) do
+    %{token: token, user_id: user_id}
+  end
+  def get_resource(_), do: nil
+
+  @spec get_user_id(Plug.Conn.t, CodeCorps.User.t | struct | map) :: String.t
+  def get_user_id(%Plug.Conn{assigns: %{current_user: %CodeCorps.User{id: id}}}, _), do: id
+  def get_user_id(_, %CodeCorps.User{id: id}), do: id
+  def get_user_id(_, %{user_id: user_id}), do: user_id
+end

lib/code_corps/analytics/segment_data_extractor.ex

@@ -0,0 +1,56 @@
+defmodule CodeCorps.Analytics.SegmentEventNameBuilder do
+  @moduledoc """
+  Used for building friendly event names for use in Segment tracking
+  """
+
+  @spec build(atom, struct) :: String.t
+  def build(action, record), do: get_event_name(action, record)
+
+  @actions_without_properties [:updated_profile, :signed_in, :signed_out, :signed_up]
+
+  defp get_event_name(action, _) when action in @actions_without_properties do
+    friendly_action_name(action)
+  end
+  defp get_event_name(:update, %CodeCorps.DonationGoal{}) do
+    "Updated Donation Goal"
+  end
+  defp get_event_name(:create, %CodeCorps.OrganizationMembership{}) do
+    "Requested Organization Membership"
+  end
+  defp get_event_name(:update, %CodeCorps.OrganizationMembership{}) do
+    "Approved Organization Membership"
+  end
+  defp get_event_name(:payment_succeeded, %CodeCorps.StripeInvoice{}) do
+    "Processed Subscription Payment"
+  end
+  defp get_event_name(:create, %CodeCorps.User{}), do: "Signed Up"
+  defp get_event_name(:update, %CodeCorps.User{}), do: "Updated Profile"
+  defp get_event_name(:create, %CodeCorps.UserCategory{}), do: "Added User Category"
+  defp get_event_name(:create, %CodeCorps.UserSkill{}), do: "Added User Skill"
+  defp get_event_name(:create, %CodeCorps.UserRole{}), do: "Added User Role"
+  defp get_event_name(:create, %{token: _, user_id: _}), do: "Signed In"
+  defp get_event_name(action, model) do
+    [friendly_action_name(action), friendly_model_name(model)] |> Enum.join(" ")
+  end
+
+  defp friendly_action_name(:create), do: "Created"
+  defp friendly_action_name(:delete), do: "Removed"
+  defp friendly_action_name(:update), do: "Edited"
+  defp friendly_action_name(action) do
+    action
+    |> Atom.to_string
+    |> String.split("_")
+    |> Enum.map(&String.capitalize/1)
+    |> Enum.join(" ")
+  end
+
+  defp friendly_model_name(model) do
+    model.__struct__
+    |> Module.split
+    |> List.last
+    |> Macro.underscore
+    |> String.split("_")
+    |> Enum.map(&String.capitalize/1)
+    |> Enum.join(" ")
+  end
+end

lib/code_corps/analytics/segment_event_name_builder.ex

@@ -0,0 +1,34 @@
+defmodule CodeCorps.Analytics.SegmentPlugTracker do
+  @moduledoc """
+  Segment tracking
+  """
+
+  alias CodeCorps.Analytics.{
+    SegmentDataExtractor,
+    SegmentTracker,
+    SegmentTrackingSupport
+  }
+
+  @spec maybe_track(Plug.Conn.t) :: Plug.Conn.t
+  def maybe_track(conn) do
+    success = successful?(conn)
+
+    action = SegmentDataExtractor.get_action(conn)
+    resource = SegmentDataExtractor.get_resource(conn)
+
+    case success && SegmentTrackingSupport.includes?(action, resource) do
+      true ->
+        user_id = SegmentDataExtractor.get_user_id(conn, resource)
+        SegmentTracker.track(user_id, action, resource)
+        mark_tracked(conn)
+      false ->
+        mark_untracked(conn)
+    end
+  end
+
+  defp successful?(%Plug.Conn{status: status}) when status in [200, 201, 204], do: true
+  defp successful?(_), do: false
+
+  defp mark_untracked(conn), do: conn |> Plug.Conn.assign(:segment_tracked, false)
+  defp mark_tracked(conn), do: conn |> Plug.Conn.assign(:segment_tracked, true)
+end

lib/code_corps/analytics/segment_plug_tracker.ex

@@ -0,0 +1,30 @@
+defmodule CodeCorps.Analytics.SegmentTracker do
+  @moduledoc """
+  Performs tracking of segment events
+  """
+
+  alias CodeCorps.Analytics.{
+    SegmentEventNameBuilder,
+    SegmentTraitsBuilder
+  }
+
+  @api Application.get_env(:code_corps, :analytics)
+
+  @doc """
+  Calls `identify` in the configured API module.
+  """
+  @spec identify(CodeCorps.User.t) :: any
+  def identify(%CodeCorps.User{} = user) do
+    @api.identify(user.id, SegmentTraitsBuilder.build(user))
+  end
+
+  @doc """
+  Calls `track` in the configured API module.
+  """
+  @spec track(String.t, atom, struct) :: any
+  def track(user_id, action, data) do
+    event = SegmentEventNameBuilder.build(action, data)
+    traits = SegmentTraitsBuilder.build(data)
+    @api.track(user_id, event, traits)
+  end
+end

lib/code_corps/analytics/segment_tracker.ex

@@ -0,0 +1,34 @@
+defmodule CodeCorps.Analytics.SegmentTrackingSupport do
+  @moduledoc """
+  Used to determine what Segment should and should not track
+  """
+
+  @doc """
+  Determines if Segment should track an action/record combination.
+  """
+  @spec includes?(atom, struct) :: boolean
+  def includes?(:create, %CodeCorps.Comment{}), do: true
+  def includes?(:update, %CodeCorps.Comment{}), do: true
+  def includes?(:create, %CodeCorps.DonationGoal{}), do: true
+  def includes?(:update, %CodeCorps.DonationGoal{}), do: true
+  def includes?(:create, %CodeCorps.OrganizationMembership{}), do: true
+  def includes?(:update, %CodeCorps.OrganizationMembership{}), do: true
+  def includes?(:create, %CodeCorps.StripeConnectAccount{}), do: true
+  def includes?(:create, %CodeCorps.StripeConnectCharge{}), do: true
+  def includes?(:create, %CodeCorps.StripeConnectPlan{}), do: true
+  def includes?(:create, %CodeCorps.StripeConnectSubscription{}), do: true
+  def includes?(:create, %CodeCorps.StripePlatformCard{}), do: true
+  def includes?(:create, %CodeCorps.StripePlatformCustomer{}), do: true
+  def includes?(:create, %CodeCorps.Task{}), do: true
+  def includes?(:update, %CodeCorps.Task{}), do: true
+  def includes?(:create, %CodeCorps.User{}), do: true
+  def includes?(:update, %CodeCorps.User{}), do: true
+  def includes?(:create, %CodeCorps.UserCategory{}), do: true
+  def includes?(:delete, %CodeCorps.UserCategory{}), do: true
+  def includes?(:create, %CodeCorps.UserRole{}), do: true
+  def includes?(:delete, %CodeCorps.UserRole{}), do: true
+  def includes?(:create, %CodeCorps.UserSkill{}), do: true
+  def includes?(:delete, %CodeCorps.UserSkill{}), do: true
+  def includes?(:create, %{token: _, user_id: _}), do: true
+  def includes?(_, _), do: false
+end