Restructure WebhookProcessor to make testing easier

Author: begedin

lib/code_corps/stripe_service/events/account_updated.ex

@@ -1,5 +1,5 @@
 defmodule CodeCorps.StripeService.Events.AccountUpdated do
-  def handle(%{"data" => %{"object" => %{"id" => id_from_stripe}}}) do
+  def handle(%{data: %{object: %{id: id_from_stripe}}}) do
     CodeCorps.StripeService.StripeConnectAccountService.update_from_stripe(id_from_stripe)
   end
 end

lib/code_corps/stripe_service/events/connect_external_account_created.ex

@@ -1,5 +1,5 @@
 defmodule CodeCorps.StripeService.Events.ConnectExternalAccountCreated do
-  def handle(%{"data" => %{"object" => %{"account" => account_id_from_stripe, "id" => id_from_stripe}}}) do
+  def handle(%{data: %{object: %{account: account_id_from_stripe, id: id_from_stripe}}}) do
     CodeCorps.StripeService.StripeConnectExternalAccountService.create(id_from_stripe, account_id_from_stripe)
   end
 end

lib/code_corps/stripe_service/events/customer_source_updated.ex

@@ -1,7 +1,7 @@
 defmodule CodeCorps.StripeService.Events.CustomerSourceUpdated do
-  def handle(%{"data" => %{"object" => %{"id" => card_id, "object" => "card"}}}) do
+  def handle(%{data: %{object: %Stripe.Card{id: card_id}}}) do
     CodeCorps.StripeService.StripePlatformCardService.update_from_stripe(card_id)
   end
 
-  def handle(%{"data" => %{"object" => %{"id" => _, "object" => _}}}), do: {:error, :unsupported_object}
+  def handle(_data), do: {:error, :unsupported_object}
 end

lib/code_corps/stripe_service/events/customer_subscription_deleted.ex

@@ -1,5 +1,5 @@
 defmodule CodeCorps.StripeService.Events.CustomerSubscriptionDeleted do
-  def handle(%{"data" => %{"object" => %{"id" => stripe_sub_id, "customer" => connect_customer_id}}}) do
+  def handle(%{data: %{object: %{id: stripe_sub_id, customer: connect_customer_id}}}) do
     CodeCorps.StripeService.StripeConnectSubscriptionService.update_from_stripe(stripe_sub_id, connect_customer_id)
   end
 end

lib/code_corps/stripe_service/events/customer_subscription_updated.ex

@@ -1,5 +1,5 @@
 defmodule CodeCorps.StripeService.Events.CustomerSubscriptionUpdated do
-  def handle(%{"data" => %{"object" => %{"id" => stripe_sub_id, "customer" => connect_customer_id}}}) do
+  def handle(%{data: %{object: %{id: stripe_sub_id, customer: connect_customer_id}}}) do
     CodeCorps.StripeService.StripeConnectSubscriptionService.update_from_stripe(stripe_sub_id, connect_customer_id)
   end
 end

lib/code_corps/stripe_service/events/customer_updated.ex

@@ -1,5 +1,5 @@
 defmodule CodeCorps.StripeService.Events.CustomerUpdated do
-  def handle(%{"data" => %{"object" => %{"id" => id_from_stripe}}}) do
+  def handle(%{data: %{object: %{id: id_from_stripe}}}) do
     CodeCorps.StripeService.StripePlatformCustomerService.update_from_stripe(id_from_stripe)
   end
 end

lib/code_corps/stripe_service/events/invoice_payment_succeeded.ex

@@ -1,5 +1,7 @@
 defmodule CodeCorps.StripeService.Events.InvoicePaymentSucceeded do
-  def handle(%{"data" => %{"object" => %{"id" => id_from_stripe, "customer" => customer_id_from_stripe}}}) do
+  def handle(%{data: %{object:
+    %{id: id_from_stripe, customer: customer_id_from_stripe}
+  }}) do
     CodeCorps.StripeService.StripeInvoiceService.create(id_from_stripe, customer_id_from_stripe)
   end
 end

lib/code_corps/stripe_service/webhook_processing/connect_event_handler.ex

@@ -13,7 +13,7 @@ defmodule CodeCorps.StripeService.WebhookProcessing.ConnectEventHandler do
     in which the first member is `:ok`, followed by one or more other elements, usually modified records.
   * `{:ok, :unhandled_event}` if the specific event is not supported yet or at all
   """
-  def handle_event(%{"type" => type} = attributes), do: do_handle(type, attributes)
+  def handle_event(%{type: type} = attributes), do: do_handle(type, attributes)
 
   defp do_handle("account.updated", attributes), do: Events.AccountUpdated.handle(attributes)
   defp do_handle("account.external_account.created", attributes), do: Events.ConnectExternalAccountCreated.handle(attributes)

lib/code_corps/stripe_service/webhook_processing/environment_filter.ex

@@ -0,0 +1,19 @@
+defmodule CodeCorps.StripeService.WebhookProcessing.EnvironmentFilter do
+  @moduledoc """
+  Used to filter events based on environment
+  """
+
+  @doc """
+  Returns true if the livemode attribute of the event matches
+  the current environment of the Phoenix application.
+
+  - livemode events are processed only in production.
+  - non-livemode events are processed in all other environments
+  """
+  def environment_matches?(%{"livemode" => livemode}) do
+    case Application.get_env(:code_corps, :stripe_env) do
+      :prod -> livemode
+      _ -> !livemode
+    end
+  end
+end

lib/code_corps/stripe_service/webhook_processing/event_handler.ex

@@ -0,0 +1,57 @@
+defmodule CodeCorps.StripeService.WebhookProcessing.EventHandler do
+  alias CodeCorps.{StripeEvent, Repo}
+  alias CodeCorps.StripeService.WebhookProcessing.{ConnectEventHandler, PlatformEventHandler}
+  alias CodeCorps.StripeService.Adapters.StripeEventAdapter
+
+  def handle(%Stripe.Event{} = api_event, handler) do
+    with {:ok, endpoint} <- infer_endpoint_from_handler(handler),
+         {:ok, %StripeEvent{} = local_event} <- find_or_create_event(api_event, endpoint)
+    do
+      call_handler(api_event, local_event, handler)
+    else
+      failure -> failure
+    end
+  end
+
+  defp infer_endpoint_from_handler(ConnectEventHandler), do: {:ok, "connect"}
+  defp infer_endpoint_from_handler(PlatformEventHandler), do: {:ok, "platform"}
+
+  defp find_or_create_event(%Stripe.Event{} = api_event, endpoint) do
+    case find_event(api_event.id) do
+      %StripeEvent{status: "processing"} -> {:error, :already_processing}
+      %StripeEvent{} = local_event -> {:ok, local_event}
+      nil -> create_event(api_event, endpoint)
+    end
+  end
+
+  defp find_event(id_from_stripe) do
+    Repo.get_by(StripeEvent, id_from_stripe: id_from_stripe)
+  end
+
+  defp create_event(%Stripe.Event{} = api_event, endpoint) do
+    with {:ok, params} <- StripeEventAdapter.to_params(api_event, %{"endpoint" => endpoint}) do
+      %StripeEvent{} |> StripeEvent.create_changeset(params) |> Repo.insert
+    end
+  end
+
+  defp call_handler(api_event, local_event, handler) do
+    # results are multiple, so we convert the tuple to list for easier matching
+    case api_event |> handler.handle_event |> Tuple.to_list do
+      [:ok, :unhandled_event] -> local_event |> set_unhandled
+      [:ok | _results]        -> local_event |> set_processed
+      [:error | _error]       -> local_event |> set_errored
+    end
+  end
+
+  defp set_errored(%StripeEvent{} = local_event) do
+    local_event |> StripeEvent.update_changeset(%{status: "errored"}) |> Repo.update
+  end
+
+  defp set_processed(%StripeEvent{} = local_event) do
+    local_event |> StripeEvent.update_changeset(%{status: "processed"}) |> Repo.update
+  end
+
+  defp set_unhandled(%StripeEvent{} = local_event) do
+    local_event |> StripeEvent.update_changeset(%{status: "unhandled"}) |> Repo.update
+  end
+end