Add REPL convenience functions

Author: weavejester

deps.edn

@@ -1,4 +1,6 @@
 {:deps {org.clojure/clojure {:mvn/version "1.12.0"}
         org.duct-framework/database.sql.hikaricp {:mvn/version "0.7.0"}
         org.duct-framework/migrator.ragtime {:mvn/version "0.5.1"}
-        integrant/integrant {:mvn/version "0.13.1"}}}
+        org.duct-framework/repl.refers {:mvn/version "0.1.0"}
+        integrant/integrant {:mvn/version "0.13.1"}
+        com.github.seancorfield/next.jdbc {:mvn/version "1.3.967"}}}

project.clj

@@ -6,4 +6,9 @@
   :dependencies [[org.clojure/clojure "1.12.0"]
                  [org.duct-framework/database.sql.hikaricp "0.7.0"]
                  [org.duct-framework/migrator.ragtime "0.5.1"]
-                 [integrant "0.13.1"]])
+                 [org.duct-framework/repl.refers "0.1.0"]
+                 [integrant "0.13.1"]
+                 [com.github.seancorfield/next.jdbc "1.3.967"]]
+  :profiles
+  {:dev {:dependencies [[org.xerial/sqlite-jdbc "3.47.0.0"]
+                        [integrant/repl "0.4.0"]]}})

src/duct/module/sql.clj

@@ -2,14 +2,18 @@
   (:require [integrant.core :as ig]))
 
 (defmethod ig/expand-key :duct.module/sql [_ _]
-  {:duct.database.sql/hikaricp
-   {:logger  (ig/refset :duct/logger)
-    :jdbcUrl (ig/var 'jdbc-url)}
-   :duct.migrator/ragtime
-   {:logger   (ig/refset :duct/logger)
-    :database (ig/ref :duct.database/sql)
-    :strategy (ig/profile
-               :main :raise-error
-               :repl :rebase
-               :test :rebase)
-    :migrations-file "migrations.edn"}})
+  (let [components {:duct.database.sql/hikaricp
+                    {:logger  (ig/refset :duct/logger)
+                     :jdbcUrl (ig/var 'jdbc-url)}
+                    :duct.migrator/ragtime
+                    {:logger   (ig/refset :duct/logger)
+                     :database (ig/ref :duct.database/sql)
+                     :strategy :rebase
+                     :migrations-file "migrations.edn"}}]
+    (ig/profile
+     :main (assoc-in components [:duct.migrator/ragtime :strategy]
+                     :raise-error)
+     :test components
+     :repl (assoc components :duct.repl/refers
+                  '{db  duct.repl.sql/db
+                    sql duct.repl.sql/sql}))))

src/duct/repl/sql.clj

@@ -0,0 +1,15 @@
+(ns duct.repl.sql
+  (:require [integrant.core :as ig]
+            [next.jdbc :as jdbc]))
+
+(defn db
+  "Get the database from the system map."
+  []
+  (val (ig/find-derived-1
+        (var-get (requiring-resolve 'integrant.repl.state/system))
+        :duct.database/sql)))
+
+(defn sql
+  "Run a string of SQL (plus any extra params) on the database."
+  [stmt & params]
+  (jdbc/execute! (db) (into [stmt] params)))

test/duct/module/sql_test.clj

@@ -27,7 +27,10 @@
             {:database   (ig/ref :duct.database/sql)
              :logger     (ig/refset :duct/logger)
              :strategy   :rebase
-             :migrations-file "migrations.edn"}}
+             :migrations-file "migrations.edn"}
+            :duct.repl/refers
+            '{db  duct.repl.sql/db
+              sql duct.repl.sql/sql}}
            (-> {:duct.module/sql {}}
                (ig/expand (ig/deprofile [:repl]))
                (ig/bind {'jdbc-url "jdbc:sqlite:"})))))

test/duct/repl/sql_test.clj

@@ -0,0 +1,17 @@
+(ns duct.repl.sql-test
+  (:require [clojure.test :refer [deftest is]]
+            [duct.repl.sql :as sql]
+            [integrant.core :as ig]
+            [integrant.repl :as igrepl]))
+
+(deftest test-user-fns
+  (let [tempfile (java.io.File/createTempFile "duct-test" ".sqlite")
+        config   (-> {:duct.module/sql {}}
+                     (ig/expand (ig/deprofile [:repl]))
+                     (ig/bind {'jdbc-url (str "jdbc:sqlite:" tempfile)}))]
+    (ig/load-namespaces config)
+    (igrepl/set-prep! (fn [] config))
+    (igrepl/go)
+    (is (= [{:foo 1}]
+           (sql/sql "SELECT 1 AS foo")))
+    (igrepl/halt)))