Create a CMakeLists.txt for the interface folder

Summary:
^

Also use it in cachebench CMakeLists.txt

___

overriding_review_checks_triggers_an_audit_and_retroactive_review
Oncall Short Name: cachelib

Differential Revision: D100197162

fbshipit-source-id: 0d1367699ce499b47fa7626d314037c6567b095b

Author: rlyerly

cachelib/CMakeLists.txt

@@ -314,6 +314,7 @@ add_subdirectory (common)
 add_subdirectory (shm)
 add_subdirectory (navy)
 add_subdirectory (allocator)
+add_subdirectory (interface)
 add_subdirectory (datatype)
 add_subdirectory (compact_cache)
 add_subdirectory (benchmarks)
@@ -326,6 +327,7 @@ install(
     common
     compact_cache
     datatype
+    interface
     navy
     shm
   DESTINATION ${INCLUDE_INSTALL_DIR}
@@ -380,6 +382,7 @@ target_link_libraries(cachelib INTERFACE
      cachelib_shm
      cachelib_navy
      cachelib_allocator
+     cachelib_interface
      )
 target_include_directories(
   cachelib
@@ -405,6 +408,7 @@ if (BUILD_SHARED_LIBS)
     cachelib_cachebench
     cachelib_common
     cachelib_datatype
+    cachelib_interface
     cachelib_navy
     cachelib_shm
     PROPERTIES

cachelib/cachebench/CMakeLists.txt

@@ -13,12 +13,6 @@
 # limitations under the License.
 
 add_library (cachelib_cachebench
-  ../interface/CacheItem.cpp
-  ../interface/Handle.cpp
-  ../interface/Stats.cpp
-  ../interface/components/FlashCacheComponent.cpp
-  ../interface/components/RAMCacheComponent.cpp
-  ../interface/utils/CoroFiberAdapter.cpp
   ./cache/Cache.cpp
   ./cache/components/Components.cpp
   ./cache/components/FlashComponent.cpp
@@ -49,19 +43,9 @@ add_library (cachelib_cachebench
   ./workload/SimpleFlashBenchmarkGenerator.cpp
   )
 
-# GCC 11's C++20 coroutine support has bugs that cause internal compiler errors
-# (segfaults) when compiling coroutine templates at -O2. Reduce optimization
-# for affected files to work around this.
-if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU"
-    AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "12")
-  set_source_files_properties(
-    ../interface/components/FlashCacheComponent.cpp
-    PROPERTIES COMPILE_OPTIONS "-O1"
-  )
-endif()
-
 add_dependencies(cachelib_cachebench thrift_generated_files)
 target_link_libraries(cachelib_cachebench PUBLIC
+  cachelib_interface
   cachelib_datatype
   cachelib_allocator
   gflags

cachelib/interface/CMakeLists.txt

@@ -0,0 +1,71 @@
+# Copyright (c) Meta Platforms, Inc. and affiliates.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_library (cachelib_interface
+  CacheItem.cpp
+  Handle.cpp
+  Stats.cpp
+  components/FlashCacheComponent.cpp
+  components/RAMCacheComponent.cpp
+  utils/CoroFiberAdapter.cpp
+)
+
+# GCC 11's C++20 coroutine support has bugs that cause internal compiler errors
+# (segfaults) when compiling coroutine templates at -O2. Reduce optimization
+# for affected files to work around this.
+if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU"
+    AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "12")
+  set_source_files_properties(
+    components/FlashCacheComponent.cpp
+    PROPERTIES COMPILE_OPTIONS "-O1"
+  )
+endif()
+
+target_link_libraries(cachelib_interface PUBLIC
+  cachelib_allocator
+)
+
+install(TARGETS cachelib_interface
+        EXPORT cachelib-exports
+        DESTINATION ${LIB_INSTALL_DIR})
+
+if (BUILD_TESTS)
+  add_library (interface_test_support STATIC
+    components/tests/CacheComponentFactory.cpp
+  )
+  target_link_libraries (interface_test_support PUBLIC
+    cachelib_interface
+    navy_test_support
+    glog::glog
+    gflags
+    GTest::gtest
+    GTest::gtest_main
+    GTest::gmock
+  )
+
+  function (add_source_test SOURCE_FILE)
+    generic_add_source_test("interface-test" "${SOURCE_FILE}"
+                     interface_test_support "${ARGN}")
+  endfunction()
+
+  # GCC ICE in gimplify_var_or_parm_decl with coroutine test macros
+  if (NOT CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
+    add_source_test (tests/InterfaceTest.cpp)
+    add_source_test (components/tests/CacheComponentTest.cpp)
+  endif()
+  add_source_test (tests/ResultTest.cpp)
+  add_source_test (components/tests/FlashCacheComponentTest.cpp)
+  add_source_test (utils/tests/CoroFiberAdapterTest.cpp)
+  add_source_test (utils/tests/ShardedSerializerTest.cpp)
+endif()