saxman.bas

Attribute VB_Name = "SaxmanModule"
' /*-----------------------------------------------------------------------------*\
' |                                                                               |
' |  Saxman.dll: Compression / Decompression of data in Saxman format             |
' |  Copyright © 2002-2004 The KENS Project Development Team                      |
' |                                                                               |
' |  This library is free software; you can redistribute it and/or                |
' |  modify it under the terms of the GNU Lesser General Public                   |
' |  License as published by the Free Software Foundation; either                 |
' |  version 2.1 of the License, or (at your option) any later version.           |
' |                                                                               |
' |  This library is distributed in the hope that it will be useful,              |
' |  but WITHOUT ANY WARRANTY; without even the implied warranty of               |
' |  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU            |
' |  Lesser General Public License for more details.                              |
' |                                                                               |
' |  You should have received a copy of the GNU Lesser General Public             |
' |  License along with this library; if not, write to the Free Software          |
' |  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA    |
' |                                                                               |
' \*-----------------------------------------------------------------------------*/
'
' VB6-port by Valley Bell (04. May 2011)

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
    (ByRef hpvDest As Any, ByRef hpvSource As Any, ByVal cbCopy As Long)

Public Const SUCCESS As Byte = &H0
Public Const ERROR_UNKNOWN As Byte = &H1
Public Const ERROR_SOURCE_FILE_DOES_NOT_EXIST As Byte = &H2

'-----------------------------------------------------------------------------------------------
' Name: SDecomp(char *SrcFile, char *DstFile, long Location, unsigned short Size)
' Desc: Decompresses the data using the Saxman compression format
'-----------------------------------------------------------------------------------------------

Public Function SDecomp(ByVal SrcSize As Long, ByRef SrcFile() As Byte, ByRef DstSize As Long, ByRef DstFile() As Byte, ByVal Location As Long) As Long

    ' Files
    Dim SrcPos As Long
    Dim DstPos As Long
    Dim SrcEnd As Long
    
    ' Info Byte, Flag, Count and Offset (with initial values)
    Dim InfoByte As Byte
    Dim IBP As Byte
    Dim IBPMask As Integer
    Dim Flag As Boolean
    Dim Count As Byte
    Dim Offset As Long
    
    Count = 0
    InfoByte = 0
    IBP = 8
    IBPMask = &H100 ' 2^8
    Flag = False
    Offset = 0
    
    ' Other info
    Dim i As Long                   ' Counter
    
'------------------------------------------------------------------------------------------------
    
    SrcPos = Location
    DstPos = &H0
    
    Call CopyMemory(SrcSize, SrcFile(SrcPos), &H2)
    SrcSize = SrcSize And &HFFFF&
    SrcPos = SrcPos + &H2
    SrcEnd = SrcPos + SrcSize
    ReDim DstFile(&H0 To &H7FFF - 1)
    
    Do While True
        If IBP = 8 Then
            IBP = 0
            IBPMask = &H1
            If SrcPos >= SrcEnd Then
                Exit Do
            End If
            InfoByte = SrcFile(SrcPos)
            SrcPos = SrcPos + &H1
        End If
        'Flag = (InfoByte >> IBP) And 1
        Flag = CBool(InfoByte And IBPMask)
        IBP = IBP + &H1
        IBPMask = IBPMask * &H2
        
        Select Case Flag
        Case False
            If SrcPos + &H1 >= SrcEnd Then Exit Do
            Offset = SrcFile(SrcPos + &H0)
            Count = SrcFile(SrcPos + &H1)
            SrcPos = SrcPos + &H2
            
            Offset = (Offset Or ((Count And &HF0) * &H10)) + &H12   ' Can be improved
            Offset = Offset Or (DstPos And &HF000&)
            Count = (Count And &HF) + &H3
            If Offset >= DstPos Then
                Offset = (Offset - &H1000&) And &HFFFF&
            End If
            
            If DstPos + Count > &H8000& Then Exit Do
            If Offset < DstPos Then
                For i = 0 To Count - 1
                    If Offset + i >= DstPos Then Exit For
                    DstFile(DstPos) = DstFile(Offset + i)
                    DstPos = DstPos + &H1
                Next i
            Else
                For i = 0 To Count - 1
                    DstFile(DstPos) = &H0
                    DstPos = DstPos + &H1
                Next i
            End If
        Case True
            If SrcPos >= SrcEnd Then Exit Do
            If DstPos > &H8000& Then Exit Do
            DstFile(DstPos) = SrcFile(SrcPos)
            SrcPos = SrcPos + &H1
            DstPos = DstPos + &H1
        End Select
    Loop

'------------------------------------------------------------------------------------------------

    DstSize = DstPos
    ReDim Preserve DstFile(&H0 To DstSize - 1)
    
    SDecomp = SUCCESS

End Function