pvm/CMakeLists.txt at master · nevergiveupcpp/pvm · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
cmake_minimum_required(VERSION 3.15)
project(pvm VERSION 1.0.0 LANGUAGES CXX)

add_library(pvm INTERFACE)
add_library(pvm::pvm ALIAS pvm)

target_include_directories(
        pvm INTERFACE
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
        $<INSTALL_INTERFACE:include>
)

target_compile_features(pvm INTERFACE cxx_std_20)

if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/dev.cmake")
    include(dev.cmake)
endif()

install(DIRECTORY include/
        DESTINATION include
        FILES_MATCHING PATTERN "*.h"
)

install(TARGETS pvm
        EXPORT pvmTargets
)

install(EXPORT pvmTargets
        FILE pvmTargets.cmake
        NAMESPACE pvm::
        DESTINATION lib/cmake/pvm
)

include(CMakePackageConfigHelpers)

configure_package_config_file(
        ${CMAKE_CURRENT_SOURCE_DIR}/cmake/pvmConfig.cmake.in
        ${CMAKE_CURRENT_BINARY_DIR}/pvmConfig.cmake
        INSTALL_DESTINATION lib/cmake/pvm
)

write_basic_package_version_file(
        ${CMAKE_CURRENT_BINARY_DIR}/pvmConfigVersion.cmake
        VERSION ${PROJECT_VERSION}
        COMPATIBILITY SameMajorVersion
)

install(FILES
        ${CMAKE_CURRENT_BINARY_DIR}/pvmConfig.cmake
        ${CMAKE_CURRENT_BINARY_DIR}/pvmConfigVersion.cmake
        DESTINATION lib/cmake/pvm
)