quiltcore-java/lib/build.gradle at 11fc626059911ee22e1183ff0a32cbe94cf3f5ae · quiltdata/quiltcore-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
import com.vanniktech.maven.publish.SonatypeHost

plugins {
    // Apply the java-library plugin for API and implementation separation.
    id 'java-library'
    id 'com.vanniktech.maven.publish' version '0.30.0'
    id 'se.patrikerdes.use-latest-versions' version '0.2.18'
    id 'com.github.ben-manes.versions' version '0.53.0'
}

useLatestVersions {
   // A blacklist of dependencies to update, in the format of group:name
   updateBlacklist = [
   ]
}

repositories {
    // Use Maven Central for resolving dependencies.
    mavenCentral()
}

dependencies {
    // AWS SDK
    implementation 'software.amazon.awssdk:s3:2.29.40'
    implementation 'software.amazon.awssdk:s3-transfer-manager:2.29.40'
    implementation 'software.amazon.awssdk.crt:aws-crt:0.33.7'

    // JSON and YAML parsing.
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.18.2'
    implementation 'com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.18.2'

    // JSON Schema validator.
    implementation 'io.vertx:vertx-json-schema:5.0.0.CR3'

    // Workarounds for Java's checked exceptions.
    implementation 'com.pivovarit:throwing-function:1.6.1'

    // Use JUnit test framework.
    testImplementation('org.junit.jupiter:junit-jupiter:5.11.4')

    // Add Log4j dependency
    implementation 'org.apache.logging.log4j:log4j-core:3.0.0-beta3'
    implementation 'org.apache.logging.log4j:log4j-api:3.0.0-beta2'
    implementation 'org.apache.logging.log4j:log4j-slf4j-impl:3.0.0-beta2'
}

// Apply a specific Java toolchain to ease working on different environments.
java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

// Enable Java 11 compatibility to support NextFlow.
tasks {
    sourceCompatibility = '11'
    targetCompatibility = '11'
}

compileJava {
    options.release.set(11)
}

test {
    useJUnitPlatform()

    testLogging {
        events "passed", "skipped", "failed"
    }
}

mavenPublishing {
    publishToMavenCentral(SonatypeHost.CENTRAL_PORTAL)

    signAllPublications()

    coordinates('com.quiltdata', 'quiltcore', '0.1.7')

    pom {
        name.set('QuiltCore')
        description.set('Java implementation of the Quilt API')
        url.set('https://quiltdata.com')
        licenses {
            license {
                name.set('Apache License, Version 2.0')
                url.set('https://www.apache.org/licenses/LICENSE-2.0.txt')
            }
        }
        developers {
            developer {
                id.set('dima')
                name.set('Dima Ryazanov')
                email.set('dima@quiltdata.io')
            }
            developer {
                id.set('drernie')
                name.set('Ernest Prabhakar')
                email.set('ernest@quiltdata.io')
            }
        }
        scm {
            url = "https://github.com/quiltdata/quiltcore-java"
            connection = "scm:git:git://github.com/quiltdata/quiltcore-java.git"
            developerConnection = "scm:git:ssh://git@github.com/quiltdata/quiltcore-java.git"
        }
    }
}