testcontainers-java/modules/neo4j/build.gradle at fb1bb165f08b4bc359b3c8e7c606c5ec76eb7523 · subshell/testcontainers-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
description = "TestContainers :: Neo4j"

def generatedResourcesDir = new File(project.buildDir, "generated-resources")
def customNeo4jPluginDestinationDir = new File(generatedResourcesDir, "custom-plugins")

sourceSets {
    customNeo4jPlugin {
        java {
            srcDir 'src/custom-neo4j-plugin'
        }
    }
    test {
        resources {
            srcDir generatedResourcesDir
        }
    }
}

task customNeo4jPluginJar(type: Jar) {
    from sourceSets.customNeo4jPlugin.output
    archiveName = "hello-world.jar"
    destinationDir = customNeo4jPluginDestinationDir

    inputs.files(sourceSets.customNeo4jPlugin.java.srcDirs)
    outputs.cacheIf { true }
    outputs.dir(customNeo4jPluginDestinationDir)
}

test.dependsOn customNeo4jPluginJar

dependencies {
    customNeo4jPluginCompileOnly "org.neo4j:neo4j:5.3.0"

    api project(":testcontainers")

    testImplementation "org.neo4j.driver:neo4j-java-driver:1.7.5"
    testImplementation 'org.assertj:assertj-core:3.20.2'
}