Add Nix support for building refloat, and use it in CI/CD

.github/actions/build/action.yml

@@ -13,10 +13,7 @@ runs:
       with:
         name: refloat
         authToken: '${{ inputs.cache-auth-token }}'
-    - uses: rrbutani/use-nix-shell-action@v1
-      with:
-        flakes: nixpkgs/nixos-24.11#gcc-arm-embedded-13, nixpkgs#gnumake, github:lukash/vesc_tool-flake/release_6_06
 
     - name: Build
       shell: bash
-      run: make -j
+      run: nix build .#refloat

.github/workflows/ci.yml

@@ -16,6 +16,7 @@ jobs:
       - uses: rrbutani/use-nix-shell-action@v1
         with:
           flakes: nixpkgs#llvmPackages_18.clang-tools, nixpkgs#pre-commit
+          extraNixOptions: --inputs-from .
 
       - name: Run clang-format
         id: clang-format

.github/workflows/create_release.yml

@@ -51,13 +51,11 @@ jobs:
         with:
           cache-auth-token: '${{ secrets.CACHIX_AUTH_TOKEN }}'
 
-      - name: Extract Config Signature
-        run: cat src/conf/confparser.h | sed -n 's/^#define .\+_SIGNATURE\W\+\([0-9]*\)/\1/p' > config_signature.txt
-
       - name: Rename Package File
         run: |
-          mv refloat.vescpkg refloat-${{env.VERSION}}.vescpkg
-          mv src/package_lib.elf refloat-${{env.VERSION}}.elf
+          cp result/refloat.vescpkg refloat-${{env.VERSION}}.vescpkg
+          cp result/refloat.elf refloat-${{env.VERSION}}.elf
+          cp result/config_signature.txt config_signature.txt
 
       - name: Install Changelog Generation Dependencies
         run: sudo apt-get install python3-git

.gitignore

@@ -10,3 +10,5 @@ ui.qml
 *.obj
 *.so
 *.vescpkg
+
+/result

Makefile

@@ -26,13 +26,16 @@ else
     MINIFY_CMD="cat"
 endif
 
+BUILD_DATE=`date --rfc-3339=seconds`
+GIT_HASH=`git rev-parse --short HEAD`
+
 package_README-gen.md: package_README.md version
 	cp $< $@
 	echo "" >> $@
 	echo "### Build Info" >> $@
 	echo "- Version: ${VERSION}" >> $@
-	echo "- Build Date: `date --rfc-3339=seconds`" >> $@
-	echo "- Git Commit: #`git rev-parse --short HEAD`" >> $@
+	echo "- Build Date: ${BUILD_DATE}" >> $@
+	echo "- Git Commit: #${GIT_HASH}" >> $@
 
 ui.qml: ui.qml.in package_name version
 	cat $< | \

flake.nix

@@ -0,0 +1,45 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.11";
+    flake-utils.url = "github:numtide/flake-utils";
+    vesc-tool.url = "github:vedderb/vesc_tool/release_6_06";
+    vesc-tool.inputs.nixpkgs.follows = "nixpkgs";
+  };
+
+  outputs = {
+    self,
+    flake-utils,
+    nixpkgs,
+    vesc-tool,
+  } @ inputs:
+    flake-utils.lib.eachSystem ["x86_64-linux"] (
+      system: let
+        pkgs = import nixpkgs {
+          inherit system;
+          overlays = [
+            (final: prev: {
+              vesc-tool = vesc-tool.packages.${system}.vesc-tool;
+            })
+            (import ./nix/overlay.nix)
+            (final: prev: {
+              refloat = prev.refloat.overrideDerivation (old: {
+                version = prev.lib.strings.removeSuffix "\n" (builtins.readFile ./version);
+                src = self;
+
+                makeFlags = [
+                  "GIT_HASH=${builtins.substring 0 8 (self.rev or self.dirtyRev)}"
+                  "BUILD_DATE=${self.lastModifiedDate}"
+                ];
+              });
+            })
+          ];
+        };
+      in {
+        packages =
+          pkgs
+          // {
+            default = pkgs.refloat;
+          };
+      }
+    );
+}

nix/overlay.nix

@@ -0,0 +1,5 @@
+final: prev: {
+  refloat = final.callPackage ./refloat.nix {
+    gcc-arm-embedded = final.gcc-arm-embedded-13;
+  };
+}

nix/refloat.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenv,
+  gcc-arm-embedded,
+  vesc-tool,
+  python3,
+}:
+stdenv.mkDerivation {
+  pname = "refloat";
+  version = "0.0.0-dev";
+
+  src = ../.;
+
+  postPatch = ''
+    # Python shebang is failing for some reason. Replace it with full shebang
+    sed -i '1s,.*,#!${lib.getExe python3},' rjsmin.py
+    echo "$version" > ./version
+  '';
+
+  doFixup = false;
+
+  nativeBuildInputs = [
+    gcc-arm-embedded
+    vesc-tool
+    python3
+  ];
+
+  installPhase = ''
+    mkdir $out
+    cp src/package_lib.elf $out/refloat.elf
+    cp refloat.vescpkg $out
+    cat src/conf/confparser.h | sed -n 's/^#define .\+_SIGNATURE\W\+\([0-9]*\)/\1/p' > $out/config_signature.txt
+  '';
+}